-- Listing 4-1: Creation Script for Sample Database and Tables

SET NOCOUNT ON;

USE master;

IF DB\_ID('Performance') IS NULL

 CREATE DATABASE Performance;

GO

USE Performance;

GO

-- Creating and Populating the Nums Auxiliary Table

SET NOCOUNT ON;

IF OBJECT\_ID('dbo.Nums', 'U') IS NOT NULL

 DROP TABLE dbo.Nums;

CREATE TABLE dbo.Nums(n INT NOT NULL PRIMARY KEY);

DECLARE @max AS INT, @rc AS INT;

SET @max = 1000000;

SET @rc = 1;

INSERT INTO dbo.Nums(n) VALUES(1);

WHILE @rc \* 2 <= @max

BEGIN

 INSERT INTO dbo.Nums(n) SELECT n + @rc FROM dbo.Nums;

 SET @rc = @rc \* 2;

END

INSERT INTO dbo.Nums(n)

 SELECT n + @rc FROM dbo.Nums WHERE n + @rc <= @max;

GO

-- Drop Data Tables if Exist

IF OBJECT\_ID('dbo.EmpOrders', 'V') IS NOT NULL

 DROP VIEW dbo.EmpOrders;

GO

IF OBJECT\_ID('dbo.Orders', 'U') IS NOT NULL

 DROP TABLE dbo.Orders;

GO

IF OBJECT\_ID('dbo.Customers', 'U') IS NOT NULL

 DROP TABLE dbo.Customers;

GO

IF OBJECT\_ID('dbo.Employees', 'U') IS NOT NULL

 DROP TABLE dbo.Employees;

GO

IF OBJECT\_ID('dbo.Shippers', 'U') IS NOT NULL

 DROP TABLE dbo.Shippers;

GO

-- Data Distribution Settings

DECLARE

 @numorders AS INT,

 @numcusts AS INT,

 @numemps AS INT,

 @numshippers AS INT,

 @numyears AS INT,

 @startdate AS DATETIME;

SELECT

 @numorders = 1000000,

 @numcusts = 20000,

 @numemps = 500,

 @numshippers = 5,

 @numyears = 4,

 @startdate = '20050101';

-- Creating and Populating the Customers Table

CREATE TABLE dbo.Customers

(

 custid CHAR(11) NOT NULL,

 custname NVARCHAR(50) NOT NULL

);

INSERT INTO dbo.Customers(custid, custname)

 SELECT

 'C' + RIGHT('000000000' + CAST(n AS VARCHAR(10)), 10) AS custid,

 N'Cust\_' + CAST(n AS VARCHAR(10)) AS custname

 FROM dbo.Nums

 WHERE n <= @numcusts;

ALTER TABLE dbo.Customers ADD

 CONSTRAINT PK\_Customers PRIMARY KEY(custid);

-- Creating and Populating the Employees Table

CREATE TABLE dbo.Employees

(

 empid INT NOT NULL,

 firstname NVARCHAR(25) NOT NULL,

 lastname NVARCHAR(25) NOT NULL

);

INSERT INTO dbo.Employees(empid, firstname, lastname)

 SELECT n AS empid,

 N'Fname\_' + CAST(n AS NVARCHAR(10)) AS firstname,

 N'Lname\_' + CAST(n AS NVARCHAR(10)) AS lastname

 FROM dbo.Nums

 WHERE n <= @numemps;

ALTER TABLE dbo.Employees ADD

 CONSTRAINT PK\_Employees PRIMARY KEY(empid);

-- Creating and Populating the Shippers Table

CREATE TABLE dbo.Shippers

(

 shipperid  VARCHAR(5) NOT NULL,

 shippername NVARCHAR(50) NOT NULL

);

INSERT INTO dbo.Shippers(shipperid, shippername)

 SELECT shipperid, N'Shipper\_' + shipperid AS shippername

 FROM (SELECT CHAR(ASCII('A') - 2 + 2 \* n) AS shipperid

 FROM dbo.Nums

  WHERE n <= @numshippers) AS D;

ALTER TABLE dbo.Shippers ADD

 CONSTRAINT PK\_Shippers PRIMARY KEY(shipperid);

-- Creating and Populating the Orders Table

CREATE TABLE dbo.Orders

(

 orderid INT NOT NULL,

 custid CHAR(11) NOT NULL,

 empid INT NOT NULL,

 shipperid VARCHAR(5) NOT NULL,

 orderdate DATETIME NOT NULL,

 filler CHAR(155) NOT NULL DEFAULT('a')

);

INSERT INTO dbo.Orders(orderid, custid, empid, shipperid, orderdate)

 SELECT n AS orderid,

 'C' + RIGHT('000000000'

 + CAST(

 1 + ABS(CHECKSUM(NEWID())) % @numcusts

 AS VARCHAR(10)), 10) AS custid,

 1 + ABS(CHECKSUM(NEWID())) % @numemps AS empid,

 CHAR(ASCII('A') - 2

 + 2 \* (1 + ABS(CHECKSUM(NEWID())) % @numshippers)) AS shipperid,

 DATEADD(day, n / (@numorders / (@numyears \* 365.25)), @startdate)

 -- late arrival with earlier date

 - CASE WHEN n % 10 = 0

 THEN 1 + ABS(CHECKSUM(NEWID())) % 30

 ELSE 0

 END AS orderdate

 FROM dbo.Nums

 WHERE n <= @numorders

 ORDER BY CHECKSUM(NEWID());

CREATE CLUSTERED INDEX idx\_cl\_od ON dbo.Orders(orderdate);

CREATE NONCLUSTERED INDEX idx\_nc\_sid\_od\_i\_cid

 ON dbo.Orders(shipperid, orderdate)

 INCLUDE(custid);

CREATE UNIQUE INDEX idx\_unc\_od\_oid\_i\_cid\_eid

 ON dbo.Orders(orderdate, orderid)

 INCLUDE(custid, empid);

ALTER TABLE dbo.Orders ADD

 CONSTRAINT PK\_Orders PRIMARY KEY NONCLUSTERED(orderid),

 CONSTRAINT FK\_Orders\_Customers

 FOREIGN KEY(custid) REFERENCES dbo.Customers(custid),

 CONSTRAINT FK\_Orders\_Employees

 FOREIGN KEY(empid) REFERENCES dbo.Employees(empid),

 CONSTRAINT FK\_Orders\_Shippers

 FOREIGN KEY(shipperid) REFERENCES dbo.Shippers(shipperid);

GO